* MAX5035 MACROMODEL
* ------------------------------
* Revision 1, 5/2005
* Model platform : PSpice
* ------------------------------
* The MAX5035 Pspice macromodel uses an averaged model of the PWM switch and is designed 
* to be used for analyzing frequency response or transient response of a MAX5035 based buck 
* converter. This averaged PWM switch model does not use actual PWM switching in simulation
* and so it can be simulated in much lesser time compared to switching models. The model
* includes all the important system poles and zeros, gains of the various MAX5035 internal 
* amplifier stages and transient properties like soft-start. It also covers the converter 
* operation in both continuous current mode(CCM) and discontinuous current mode(DCM). 

*********************
* HOW TO USE THE MODEL.
*********************
* The MAX5035 model works in two modes. The first mode is for the transient analysis and 
* the seceond mode is for frequency domain analysis. By default the model runs in transient
* analysis mode. These modes can be set by assigning '1' or '0' to the 'FR_ON' parameter.
* In transient analysis mode the model internally finds if the converter is in CCM or in DCM.
* For this some of the external component values has to be entered as parameters other than
* connecting the components to the model. Details on the parameters to be entered is given 
* below. For proper results always make sure that the values entered as parameters are same
* as the external component values. Also use a maximum time step of 0.5uS during simulation
* for proper internal switching between CCM and DCM. Use SET_VOUT parameter to specify the 
* desired output voltage and connect the output node directly to the 'FB' pin. 
* In frequency domain mode the model can not differentiate between DCM and CCM and so the 
* 'DCM_ON' parameter should be used to specify the mode for which the frequency response
* is sought. Output at Pin '10' can be used during transient analysis to find if the 
* converter is in CCM or DCM for a particular operating condition and this information 
* can be used during frequency domain analysis. Pin '10' is '1' while the converter is in
* DCM and '0' while in CCM.

******************
* PARAMETERS TO BE ENTERED DURING SIMULATION:
******************
* L        :Inductance of the external inductor connected(Default is 68uH).
* RL       :DC resistance of the inductor(Default is 100m Ohms).
* SET_VOUT :Output set voltage(Default is 5.0 Volts).
* TS       :Oscillator time period(Default is 1/125kHz = 8uS).
* VFB      :Nominal forward drop of the external freewheeling diode at operating current.
*           (Default is 300m Volts).
* FR_ON    :Frequency response mode'ON' for '1', 'OFF' for '0'(Zero). Use only when the 
*           model is used for the frequency response analysis(Default is'0'(Zero)). 
* DCM_ON   :To be used with 'FR_ON' during frequency response analysis. Ignored otherwise.
*           Discontinuous conduction mode(DCM) is 'ON' for '1' and Continuous conduction 
*           mode(CCM) is 'ON' for '0'(Zero).(Default is '0').  
  
******************
* MODEL LIMITATIONS:
******************
*1. Current limit function, Pulse skip mode are not modeled.
*2. Pins BST, SGND and ON/OFF are not modeled.
*3. External freewheeling diode need not be connected during simulation but the
*   nominal forward drop of the diode at the operating current has to be entered
*   as a parameter which will be used in the model simulation. The change in diode
*   drop with current is assumed to be linear.
*4. During frequency domain analysis the model can not differentiate between DCM 
*   and CCM. This information has to be provided by the designer to the model
*   while doing frequecny response analysis. Output at Pin '10' can be used during
*   transient analysis to find if the converter is in CCM or DCM for a particular 
*   operating condition and this information can be used during frequency domain
*   analysis. Pin '10' is '1' while the converter is in DCM and '0' while in CCM.
*****************
* Connections
* 2  = VD
* 4  = FB 
* 6  = GND
* 7  = VIN
* 8  = LX
* 10 = DCM
* Pin number '10' is not an actual device pin. Pin '10' output is '1' while the 
* converter is in DCM and '0' while in CCM.
*$
*****************
.SUBCKT MAX5035 2 4 6 7 8 10
+PARAMS: L = 68u
+PARAMS: RL = 100M
+PARAMS: SET_VOUT = 5.0
+PARAMS: TS = 8u
+PARAMS: VFB = 300M
+PARAMS: FR_ON = 0
+PARAMS: DCM_ON = 0
*****************
*REGULATOR
VREG 30 6 7.8V
DREG 2 A30 DS
VREG1 B31 A30 2V
EREG B31 6 7 6 1
RO 30 2 150
VREF 31 6 1.221
*****************
RFB 49 34 5.1K
DFB 34 31 DB
DIN 6 4 DB
VINT 35 6 3.5V
XBUF 35 6 34 36 36 EA_5035
*SOFT START
ISS1 6 39 0.18U
CSS1 39 6 100P
DSS2 39 38 DS
RSS2 38 37 100
VSS1 A37 6 PULSE(0M 3 100N 10N 10N 10 10)
ESS2 37 A37 VALUE={3*FR_ON}
ESS1 40 6 74 6 1
DSS1 41 40 DS
CSS2 41 6 3P
RSS1 41 31 150K
*****************
ESS4 75 6 39 6 1
DSS4 75 74 DS
DSS5 76 74 DS
VSS4 76 6 630M
***************** 
XEA 35 6 41 43 45 EA_5035
R1 36 43 3.4MEG
R2 42 43 230K
C1 36 42 28P
R3 43 44 5.15MEG
C2 44 45 10P
*****************
DSS3 45 21 DS
VSS3 21 20 0M
ESS3 20 6 39 6 0.91
*****************
*SECOND STAGE
GIS 6 52 45 6 20.36U
RIS 52 6 100K
CIS 52 6 2.56P
*****************
*630mV OFFSET
EEA 48 6 52 6 1
DEA1 48 A45 DS
VDEA A45 B45 630M
RDEA B45 6 1MEG
*****************
*MAX DUTY CYCLE
GPWM 6 46 B45 6 434.28U
RPWM 46 6 1K
DPWM 46 47 DS
DP1 6 46 DS
VLIM 47 6 0.949
*****************
*DUTY CYCLE IN CURRENT 
GDTY 6 51 46 6 1
VDTY 51 6 0V
*****************
*FEEDBACK
EFB 49 6 VALUE={V(4,6)*1.221/SET_VOUT}
*****************
*CCM-DCM Boundary
HIO1 55 6 VOUT 1
EBND1 56 6 VALUE={((V(7,6)-(V(55,6)*(RL+0.4))-V(4,6))*TS*V(46,6))/(2*L)}
GBND2 6 58 56 55 10M
GBND1 6 58 58 61 0.1M
RBND1 58 6 10MEG
CBND 58 6 0.1P
DBND1 6 58 DS
DBND2 58 60 DS
VBND1 60 6 1V
VBND2 61 6 0.5V
*MODE
EBND2 57 6 58 6 1
RMODE1 57 59 10K
GMODE 59 62 VALUE={V(59,62)*(60N + FR_ON)}
VMODE 62 6 {DCM_ON}
EDCM 10 6 59 6 1
*****************
*CCM SWITCH AVERAGE MODEL
ECCM1 66 6 VALUE={(V(7,6)-V(55,6)*0.4+VFB)*V(46,6)-VFB-V(55,6)*RL}
ECCM3 67 6 VALUE={V(55,6)*V(46,6)}
*********
*CCM O/P DRIVE
DCCM 54 53 DS
VOUT 53 8 0V
ECCM 54 6 POLY(2) 66 6 60 59 0 0 0 0 1
GCCM 7 53 POLY(2) 67 6 60 59 0 0 0 0 1
*****************
*DCM SWITCH AVERAGE MODEL
*I(Re)=(D^2*TS/2*L)*V(Re) AND P(t) 
EDCM1 71 6 VALUE={V(46,6)**2*TS*0.5*V(7,53)/L}
EDCM2 72 6 VALUE={V(71,6)*V(7,53)/V(53,6)} 
*********
*DCM O/P DRIVE
GDCM1 7 53 POLY(2) 71 6 59 6 0 0 0 0 1
GDCM2 6 53 POLY(2) 72 6 59 6 0 0 0 0 1
*TO AVOID O/P GOING -VE
VDCM A53 6 20M
DDCM A53 53 DS
*****************
Isup 7 6 270u
*****************
.MODEL MOSFET PMOS(VTO=-0.2 KP=12.57E-4)
.MODEL DS D(N=1M)
.MODEL DB D(IS=100E-14)
*****************
.ENDS
*****************
.SUBCKT EA_5035 10 18 17 15 26
IBIAS 10 12 7.978UA 
M2 14 15 12 10 MP
M1 13 16 12 10 MP
VOS 17 16 1M
RD1 13 18 10K    
RD2 14 18 10K
C1 13 14 2.2P     
GA 25 20 14 13 100U  
RO1 25 20 123.83K
GB 26 20 25 20 1M
RO2 26 20 178K
EF 27 20 26 20 1   
CC 25 27 6.297P       
DP1 26 10 DB           
DP2 18 26 DB
EG1 20 18 10 18 0.5
.MODEL DA D(IS=100E-14 RS=0.5k)
.MODEL DB D(N=10M)
.MODEL MP PMOS(VTO=-0.2 KP=12.57E-4)
.ENDS
*****************
*$