* PSpice Model Editor - Version 10.0.0

*$
* MAX9012 MACROMODEL
* ------------------------------
* Revision 0, 2/2004
* ------------------------------
* MAX9012 is a dual high-speed comparator operating from a single 4.5V to 5.5V supply
* with a propagation delay of 5ns.
* ------------------------------
* Connections
*   1  = INA+
*   2  = INA-
*   3  = INB+
*   4  = INB-
*   5  = GND
*   6  = OUTB
*   7  = OUTA
*   8  = VCC
****************
.SUBCKT MAX9012CMP 1 2 3 6 7
*INPUT STAGE
****************
RQ 1 6 2.174K
****************
VOS 99 2 0.7M
****************
IEE 1 11 100U
Q1 12 3 11 QX
Q2 13 99 11 QY
CIN 3 99 1.5P
RC1 12 6 258.5
RC2 13 6 258.5
*INPUT COMMON-MODE RANGE
DCMH 11 150 DX
RCMH 150 151 1 
VCMH 1 151 1.2
DCML 152 11 DX
RCML 152 153 1 
VCML 153 6 0.5 
****************
*INTERMEDIATE STAGE
GPS 14 6 1 6 2.4U
GCM 14 6 11 6 537.206N
GA 6 14 12 13 63.35M
RA 14 6 100K
CA 14 6 1E-18
**************
*LOGIC SCALING
GLQ 6 36 14 6 5M
RLQ 36 6 1K 
DLHQ 36 32 DX
VLHQ 32 6 2.9
DLLQ 33 36 DX
VLLQ 33 6 0.5
**************
*DELAY,RISE AND FALL TIME
EDELQ 38 6 36 6 2
RSDELQ 38 39 50
T1Q 39 6 40 6 ZO=50 TD=3.923N
RTERMQ 40 6 50 
CTERMQ1 40 6 40P
DCQ3 40 52 DX
CTERMQ2 52 6 21.681P
DCQ4 52 53 DX
ECQ4 53 6 40 6 1
**************
*SHORT-CIRCUIT PROTECTION
ESCQ1 400 6 40 6 1
DSCQ1 400 44 DX
DSCQ2 46 44 DX
ISCQ 44 45 20M
GSCQ 44 45 145 6 10M
DSCQ3 45 400 DX
DSCQ4 45 46 DX
*****
FSCQO 6 145 VSCQ 1
DSCQS1 145 146 DX
VSCSQ 146 6 1
DSCQS2 6 145 DX 
*****
VSCQ 46 7 0
****************
*MODELS USED
.MODEL QX PNP(BF=98.354)
.MODEL QY PNP(BF=103.867)
.MODEL DX D(N=0.001 TT=1E-15 CJO=3E-16)
****************
.ENDS  
*$