* MAX16820 MACROMODEL
* ----------------------------
* Revision 1.0 12/2007
* ----------------------------
* Model Platform: Spice3
* ----------------------------
* The MAX16820, step-down constant-current high-brightness LEDHB LED) driver
* provide a cost effective solution for automotive interior/exterior lighting,
* architectural and ambient lighting, LED bulbs such as MR16 and other LED 
* illumination applications. 
* ----------------------------
* Connections: Model pin names are same as the device pin names.
* ----------------------------
* Sub circuit name: MAX16820 
* ----------------------------
* Note: Feedback loop characteristics of the VCC regulator are not modeled.
* ----------------------------
**************************************************
.SUBCKT MAX16820 IN CSN DIM GND DRV VCC 
**************************************************
*UVLO (4.7V-ON,4.2V-OFF, 0.5V Hyst)
VUV VUV1 GND 4.7V 
GUV GND UV1 POLY(2) IN VUV1 UV1 GND 0 1M 0.5M
DUV1 GND UV1 DA
CUV UV1 GND 1P
DUV2 UV1 V1 DA
VUV1 V1 GND 1V
*************
*LDO 
EVIN1 VIN GND IN GND 1 
RVIN VIN VCC1 10K
DVCC1 VCC1 VCC2 DA
VCC1 VCC2 GND 5V
EVCC1 VCC3 GND POLY(2)UV1 GND VCC1 GND 0 0 0 0 1
EVCC2 VCC4 VCC3 IN VCC2 0.5M 
RVCC1 VCC4 VCC5 4
IVCC VCC5 VCC6 45M
DCC2 VCC6 VCC5 DA
VLDCS VCC6 VCC 0V
*************
*LDO UVLO(3.56V And 50mV Hyst)
VLUV LVUV1 GND 3.56V 
GLUV GND LUV1 POLY(2) VCC LVUV1 LUV1 GND 0 1M 0.05M
DLUV1 GND LUV1 DA
CLUV LUV1 GND 1P
DLUV2 LUV1 V1 DA
*************
*DIM Buffer(2.17V-High,1.66V-Low, 0.5V Hyst)
VDIM DIM1 GND 2.17V 
GDIM GND DIM2 POLY(2) DIM DIM1 DIM2 GND 0 1M 0.5M
DDIM1 GND DIM2 DA
CDIM DIM2 GND 0.5P
DDIM2 DIM2 V1 DA
*Delay(100nS)
EDIM1 DIM3 GND DIM2 GND 2
RDM1 DIM3 DIM4 1K
TDM1 DIM4 GND DIM5 GND ZO=1K TD=98N
RDM2 DIM5 GND 1K
*************
*CS comparator
*Input Current
VCSC CS5 CSN 0.2V
RCSC CS5 CS6 200K
DCSC CS6 IN DA
******
VCSREF CSREF IN -210MV
RCS4 CSN CSNA 62K
CCS1 CSNA IN 1P
GCS GND CS1 POLY(2) CSREF CSNA CS1 GND 0 10M 0.2M
DCS1 GND CS1 DA
CCS CS1 GND 0.1P
DCS2 CS1 V1 DA
*Delay(82nS)
ECS1 CS2 GND CS1 GND 2
RCS1 CS2 CS3 1K
TCS1 CS3 GND CS4 GND ZO=1K TD=80N
RCS2 CS4 GND 1K
**************
*Gate Driver
EAND1 AND1 GND POLY(2) LUV1 GND DIM5 GND 0 0 0 0 1
EAND2 AND2 GND POLY(2) AND1 GND V1 CS4 0 0 0 0 1
EOUT GD1 GND POLY(2) V1 AND2 VCC GND 0 0 0 0 1
***
*OUTPUT
MP1 DRVL PG VCCL VCCL MP1 L=1U W=1396U
MN1 DRVL NG GNDL GNDL MN1 L=1U W=1310U
CLO1 DRVL GNDL 75P
***
CGS1 PG VCC 10P
RG1 GD1 PG 50
DG1 GD1 PG DB
***
CGS2 NG GND 10P
RD2 GD1 NG 50
DG2 NG GD1 DB 
**************
MCL DRV CG GND GND MN1 L=1U W=50U
ECG1 CG GND POLY(2) DRV GND V1 LUV1 0 0 0 0 1
**************
*Lead Iductance
LVCC VCC VCCL 2N
LDRV DRV DRVL 2N
LGND GND GNDL 2N
**************
***Supply current
***Bias
GSUP1 IN GND UV1 GND 425U
FSUP1 IN GND VLDCS 1
**************************************************
.MODEL MP1 PMOS(VTO=-0.7 KP=50E-6)
.MODEL MN1 NMOS(VTO=0.7 KP=100E-6)
.MODEL DA D(IS=100E-14 N=1M)
.MODEL DB D(IS=100E-14)
**************************************************
.ENDS MAX16820